opencog-atomspace-rocks / tests / persist / rocks / space-wye-test.scm

#! /usr/bin/env guile
-s
!#
;
; space-wye-test.scm
; Test wye-shaped inheritance patterns for multiple atomspaces.
;
(use-modules (srfi srfi-1))
(use-modules (opencog) (opencog test-runner))
(use-modules (opencog persist) (opencog persist-rocks))

(include "test-utils.scm")
(whack "/tmp/cog-rocks-space-wye-test")

(opencog-test-runner)

; -------------------------------------------------------------------
; Common setup, used by all tests.

(define (setup-and-store)
	(define left-space (cog-atomspace))
	(define right-space (AtomSpace))
	(define top-space (AtomSpace (list left-space right-space)))

	; Splatter some atoms into the various spaces.
	(cog-set-atomspace! left-space)
	(set-cnt! (Concept "foo") (FloatValue 1 0 3))

	; Put different variants of the same atom in two parallel spaces
	(cog-set-atomspace! right-space)
	(set-cnt! (Concept "bar") (FloatValue 1 0 4))

	(cog-set-atomspace! top-space)
	(set-cnt! (ListLink (Concept "foo") (Concept "bar")) (FloatValue 1 0 8))

	; Store the content. Store the Concepts as well as the link,
	; as otherwise, the TV's on the Concepts aren't stored.
	(define storage (RocksStorageNode "rocks:///tmp/cog-rocks-space-wye-test"))
	(cog-set-value! storage (*-open-*))
	(cog-set-value! storage (*-store-frames-*) top-space)
	(cog-set-value! storage (*-store-atom-*) (ListLink (Concept "foo") (Concept "bar")))
	(cog-set-value! storage (*-store-atom-*) (Concept "foo"))
	(cog-set-value! storage (*-store-atom-*) (Concept "bar"))
	(cog-set-value! storage (*-close-*))
)

; -------------------------------------------------------------------
; Test ability to restore the above.

(define (test-wye)
	(setup-and-store)

	; (cog-rocks-open "rocks:///tmp/cog-rocks-space-wye-test")
	; (cog-rocks-stats)
	; (cog-rocks-get "")
	; (cog-rocks-close)

	(define new-base (AtomSpace))
	(cog-set-atomspace! new-base)

	; Load everything.
	(define storage (RocksStorageNode "rocks:///tmp/cog-rocks-space-wye-test"))
	(cog-set-value! storage (*-open-*))

	; Load all of the AtomSpaces.
	(define top-space (cog-value-ref (cog-value storage (*-load-frames-*)) 0))
	(cog-set-atomspace! top-space)

	; Now load the AtomSpace itself
	(cog-set-value! storage (*-load-atomspace-*) (cog-atomspace))
	(cog-set-value! storage (*-close-*))

	; Verify that a wye pattern was created.
	(define left-space (cog-outgoing-atom top-space 0))
	(define right-space (cog-outgoing-atom top-space 1))
	(test-assert "wye-unequal" (not (equal? left-space right-space)))
	(test-assert "wye-name" (not (equal?
		(cog-name left-space)
		(cog-name right-space))))

	; Work on the current surface, but expect to find the deeper ListLink.
	(define lilly (ListLink (Concept "foo") (Concept "bar")))

	; Verify appropriate atomspace membership
	(test-equal "top-space" top-space (cog-atomspace lilly))
	(test-equal "foo-space" left-space (cog-atomspace (gar lilly)))
	(test-equal "bar-space" right-space (cog-atomspace (gdr lilly)))

	; Verify appropriate values
	(test-equal "left-tv" 3 (get-cnt (cog-node 'Concept "foo")))
	(test-equal "right-tv" 4 (get-cnt (cog-node 'Concept "bar")))
	(test-equal "top-tv" 8 (get-cnt lilly))
)

(define wye "test wye pattern")
(test-begin wye)
(test-wye)
(test-end wye)

; ===================================================================
(whack "/tmp/cog-rocks-space-wye-test")
(opencog-test-end)